Home » パワーポイントマクロ・PowerPoint VBAの使い方 » グラフ・Chart » PowerPoint VBAでグラフを削除する

PowerPoint VBAでグラフを削除する

対象：PowerPoint2007, PowerPoint2010, PowerPoint2013, Windows版PowerPoint2016

「powerpoint vba グラフ削除」
という検索で、このサイト・インストラクターのネタ帳へのアクセスがありました。

PowerPoint VBA（Visual Basic for Applications）でグラフを削除するには、どのようなコードを書けばいいのかを探している方による検索でしょうか。

いつものように簡単なマクロをいくつか作ってみました。

［スポンサードリンク］

アクティブスライドのグラフをすべて削除するサンプルマクロ

以下のようなマクロで、アクティブなスライド上のすべてのグラフを削除できます。

Sub アクティブスライドのグラフを削除する()
　With ActiveWindow.Selection.SlideRange.Shapes
　　Dim i As Long
　　For i = .Count To 1 Step -1
　　　If .Item(i).HasChart Then
　　　　.Item(i).Delete
　　　End If
　　Next
　End With
End Sub

For～Nextループを「Step -1」で回して、
　　With ActiveWindow.Selection.SlideRange.Shapes
　　　For i = .Count To 1 Step -1

各ShapeオブジェクトのHasChartプロパティを調べ、グラフを持ったShapeだったときに、
　　　　If .Item(i).HasChart Then

Shape.Deleteメソッドで削除を行っています。
　　　　　.Item(i).Delete

PowerPoint VBAの場合For Each～Nextループで削除を行うと失敗することがある

Excelマクロ等の経験があって、PowerPointマクロの経験があまりない方だと、以下のようなFor Each～Nextループを使ったマクロを思いつくかもしれません。

Sub アクティブスライドのグラフを削除する_上手く動かない例()
　Dim shp As Shape
　For Each shp In ActiveWindow.Selection.SlideRange.Shapes
　　If shp.HasChart Then
　　　shp.Delete
　　End If
　Next
End Sub

スライドにグラフが一つしかなければ、このFor Each～Nextループを使ったマクロでもグラフを削除できますが、複数のグラフが存在しているスライドではグラフがいくつか残ってしまいます。

For Each～Nextループの回り方が、Excel VBAとPowerPoint VBAでは異なるためです。

そのため、先にご紹介したマクロでは、
　　With ActiveWindow.Selection.SlideRange.Shapes
　　　For i = .Count To 1 Step -1
と、For～Nextループを「Step -1」で回しています。

アクティブプレゼンテーションのグラフをすべて削除するサンプルマクロ

アクティブプレゼンテーション上のすべてのグラフを削除するのなら以下のようなマクロです。

Sub アクティブプレゼンテーションでグラフを削除する()
　Dim sld As Slide
　For Each sld In ActivePresentation.Slides

　　With sld.Shapes
　　　Dim i As Long
　　　For i = .Count To 1 Step -1
　　　　If .Item(i).HasChart Then
　　　　　.Item(i).Delete
　　　　End If
　　　Next i
　　End With

　Next sld
End Sub

アクティブプレゼンテーション上の全スライドに対するFor Each～Nextループの中で、
　　For Each sld In ActivePresentation.Slides

各スライド上の、全Shapeに対するFor～Nextループを「Step -1」で回して、
　　　With sld.Shapes
　　　　For i = .Count To 1 Step -1

グラフを持っているShapeだった場合に削除を行っています。
　　　　If .Item(i).HasChart Then
　　　　　.Item(i).Delete

最終更新日時：2021-06-08 14:30

▼『いちばんやさしい PowerPoint VBA の教本』は、一番易しいパワポマクロ入門書、というわけではありませんので、ご注意ください。
いちばんやさしいPowerPoint VBAの教本
［スポンサードリンク］

Home » パワーポイントマクロ・PowerPoint VBAの使い方 » グラフ・Chart » PowerPoint VBAでグラフを削除する

『インストラクターのネタ帳』では、2003年10月から平日のほぼ毎日、Microsoft Officeの使い方などを紹介し続けています。
Pythonの外部ライブラリOpenPyXL（オープンパイエクセル）の入門書を、Excel VBAユーザーに向けに書きました↓↓ Pythonの文字列フォーマットの基本をキンドル本としてまとめました↓↓ 小数とPythonのdecimalモジュールの基本をキンドル本としてまとめました↓↓ 図形を操作するExcel VBAの基本を解説したキンドル本を出しました↓↓ グラフを操作するExcel VBAの基本を解説したキンドル本です↓↓ 『インストラクターのネタ帳』を運営する伊藤潔人が、初めて書かせていただいた書籍です↓↓ PowerPoint VBA本は、実はオブジェクトブラウザーの使い方を徹底的に解説した本です↓↓ Excel VBAユーザーを対象とした、Word VBAの入門書をキンドル本として出しました↓↓ 日経BP社から出版された、Excel VBAユーザー向けのPython超入門書です↓↓ 上記の『Excel VBAユーザーのためのPythonプログラミング』の元になったキンドル本です↓↓ 数式を使った条件付き書式設定が苦手な方に向けたKindle本を書きました↓↓
3年前(2021年4月)の
人気記事
1位:Windows 10で手書き入力するIMEパッドを表示するには
2位:IF関数で○○以上××以下という条件を指定する
3位:右から（後から・末尾から）n文字を削除したい
4位:IF関数で空白なら空白にする
5位:COUNTIF関数で「○○以上」「○○以下」の指定
6位:IF関数で空白でない場合・空白でなければの書き方
7位:左から（前から・先頭から）n文字削除する方法



「グラフ・Chart」の記事一覧

検索


Copyright © インストラクターのネタ帳 All Rights Reserved.

.